1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
;; The MIT License (MIT)
;;
;; Copyright (c) 2013-2014 Olivier Gayot
;;
;; Permission is hereby granted, free of charge, to any person obtaining a copy
;; of this software and associated documentation files (the "Software"), to deal
;; in the Software without restriction, including without limitation the rights
;; to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
;; copies of the Software, and to permit persons to whom the Software is
;; furnished to do so, subject to the following conditions:
;;
;; The above copyright notice and this permission notice shall be included in
;; all copies or substantial portions of the Software.
;;
;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
;; IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
;; FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
;; AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
;; LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
;; OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
;; THE SOFTWARE.
extern malloc
extern free
%include "public.asm"
section .text
list_init: ;; {{{
mov QWORD [rdi + list_t.first], 0 ; first = NULL
mov DWORD [rdi + list_t.size], 0 ; size = 0
ret
;; }}}
list_new: ;; {{{
call list_new_raw
test rax, rax
je .end
mov rdi, rax
call list_init
.end:
ret
;; }}}
list_new_raw: ;; {{{
enter 0, 0
mov rdi, list_t_size
call malloc
leave
ret
;; }}}
list_clear: ;; {{{
enter 0, 0
mov ecx, [rdi + list_t.size] ; load the size of the list into the counter
test ecx, ecx
je .end
mov rsi, QWORD [rdi + list_t.first]
; the list is reset to its initial state
mov DWORD [rdi + list_t.size], 0
mov QWORD [rdi + list_t.first], 0
.loop:
push QWORD [rsi + elem_t.next]
push rcx
mov rdi, rsi
call free
pop rcx
pop rsi
dec ecx
test ecx, ecx
jne .loop
.end:
leave
ret
;; }}}
list_append: ;; {{{
enter 0x18, 0
mov [rsp], rdi
mov [rsp + 8], rsi
mov rdi, elem_t_size
call malloc
test rax, rax
jne .malloc_succeed
mov rax, -1
jmp .end
.malloc_succeed:
; set the new element
mov rsi, QWORD [rsp + 8]
mov QWORD [rax + elem_t.next], 0
mov QWORD [rax + elem_t.value], rsi
mov rdi, [rsp]
mov ecx, [rdi + list_t.size]
.loop:
test ecx, ecx
je .set_elem
dec ecx
mov rdi, QWORD [rdi + elem_t.next]
jmp .loop
.set_elem:
; set the next element
mov [rdi], rax
; increment size
mov rdi, QWORD [rsp]
inc DWORD [rdi + list_t.size]
xor rax, rax
.end:
leave
ret
;; }}}
list_apply: ;; {{{
enter 0x14, 0
mov QWORD [rsp], rsi
mov ecx, DWORD [rdi + list_t.size]
.loop:
test ecx, ecx
je .end
dec ecx
; elem = list->first or elem = elem->next
mov rdi, QWORD [rdi]
; backup our registers
mov DWORD [rsp + 8], ecx
mov QWORD [rsp + 0xc], rdi
mov rdi, QWORD [rdi + elem_t.value]
call QWORD [rsp]
; get back the registers
mov ecx, DWORD [rsp + 8]
mov rdi, QWORD [rsp + 0xc]
jmp .loop
.end:
leave
ret
;; }}}
; vim:ft=nasm
|
